int WIDTH=799;
int HEIGHT=490;
float ECOL=0.3;
float EDRAG=0.999;
float EG=0.25;
int N;
int NS;
//long CT=0;
int ITT=1;
float GAP;
float RIPRATIO=9999;

//fabrix
int NCOLS=65;
int NROWS=30;
int CurtainWidth=600;
int TopRail=20;

int PINMODE=0;
int TEARMODE=0;


float[] PX = new float[NCOLS * NROWS];
float[] PY = new float[NCOLS * NROWS];
float[] PX_OLD = new float[NCOLS * NROWS];
float[] PY_OLD = new float[NCOLS * NROWS];
boolean PINNED[]= new boolean [NCOLS * NROWS];

int STICKA[] = new int[(2*NCOLS*NROWS)-NROWS-NCOLS];
int STICKB[] = new int[(2*NCOLS*NROWS)-NROWS-NCOLS];
float STICKLENGTH[] = new float[(2*NCOLS*NROWS)-NROWS-NCOLS];
boolean STICKPRESENT[] = new boolean[(2*NCOLS*NROWS)-NROWS-NCOLS];

boolean RUNNING=true;
boolean DISP=true;
boolean FULLSHEET=true;

void setup() {
  size(800, 600, P2D);

  reset();

}

void draw() {

background(0,0,0,0);
noFill();
stroke(255);
rect(0,0,WIDTH,HEIGHT);

renderbuttons();
//if(CT++>3000) {reset(); RUNNING=false;} //fuze

if (RUNNING) {
updatepoints();

for (int i=0;i<ITT;i++) {
updatesticks();
constrainpoints();
}


}

if (mousePressed &&  mouseX<WIDTH && mouseY<HEIGHT) {

if ((mouseButton == LEFT) && RUNNING) {
   if (DISP) {nickmousemove();} else {nickmousedelete();}

} else if (mouseButton == RIGHT) {nickmousedelete();}

}

renderpoints();
}

void renderpoints() {

  //points
 for (int i=0;i<N;i++) {
   if (PINNED[i]==true) {fill(255,0,0); ellipse(PX[i],PY[i],5,5);} else {fill(255);}
  
 }

//lines
stroke (164,164,164);
 for (int i=0;i<NS;i++) {
   
   if (STICKPRESENT[i]) {
     line(PX[STICKA[i]],PY[STICKA[i]],PX[STICKB[i]],PY[STICKB[i]]);
       }
 }

}

void updatesticks() {
for (int i=0;i<NS;i++) {
  if (STICKPRESENT[i]) {
  float dx,dy, dist, diff, percent, offx, offy;
  dx=PX[STICKA[i]]-PX[STICKB[i]];
  dy=PY[STICKA[i]]-PY[STICKB[i]];
  dist=sqrt((dx*dx)+(dy*dy));
  
  if (dist>(RIPRATIO*GAP)) {STICKPRESENT[i]=false;} else {
  
  diff=STICKLENGTH[i]-dist;
 
 if (diff<0) {
 
  percent=diff/dist/2;
  offx=dx*percent;
  offy=dy*percent;
  
 if (!PINNED[STICKB[i]]) { PX[STICKB[i]]-=offx;  PY[STICKB[i]]-=offy;}
 if (!PINNED[STICKA[i]]) { PX[STICKA[i]]+=offx;  PY[STICKA[i]]+=offy;}
 }
 
  }
 
  }
 }
}


void constrainpoints() {
 
 float VX,VY;

for (int i=0;i<N;i++)
{

  
  VX=(PX[i]-PX_OLD[i])*EDRAG;
  VY=(PY[i]-PY_OLD[i])*EDRAG;


if (PX[i]>WIDTH) 
 {
   PX[i]=WIDTH;
   PX_OLD[i]=(PX[i]+(VX*ECOL));
 }
 else if (PX[i]<0)
  {
    PX[i]=0;
    PX_OLD[i]=(PX[i]+(VX*ECOL));
  }
  
  if (PY[i]>HEIGHT) 
 {
   PY[i]=HEIGHT;
   PY_OLD[i]=(PY[i]+(VY*ECOL));
 }
 else if (PY[i]<0)
  {
    PY[i]=0;
    PY_OLD[i]=(PY[i]+(VY*ECOL));
  }
  
} 

}




void updatepoints() {
 
 float VX,VY;

for (int i=0;i<N;i++)
{
 
  if (!PINNED[i]) {
  
  VX=(PX[i]-PX_OLD[i])*EDRAG;
  VY=(PY[i]-PY_OLD[i])*EDRAG;
  PX_OLD[i]=PX[i];
  PY_OLD[i]=PY[i];
  PX[i]+=VX;
  PY[i]+=VY;
  PY[i]+=EG;

  }

} 

}

void reset() {
  
  
  float LM;

  int INDEX;
  int P;
  
  if (FULLSHEET) {NROWS=30;} else {NROWS=15;}
  
  N=NCOLS*NROWS;
  NS=(2*NCOLS*NROWS)-NROWS-NCOLS;
  
  LM=(WIDTH-CurtainWidth)/2;
  GAP=CurtainWidth/(NCOLS-1);

  //points first
  for (int R=0;R<NROWS;R++) {
    for (int C=0;C<NCOLS;C++) {
      INDEX=(R*NCOLS)+C;
      PX[INDEX]=LM+(GAP*C);
      PX_OLD[INDEX]=LM+(GAP*C)+random(-4,4);
      PY[INDEX]=TopRail;
      PY_OLD[INDEX]=TopRail+random(-4,4); 
      PINNED[INDEX]=false; 
    }
  }  
  
  P=0;
  //now horizontal sticks
    for (int R=0;R<NROWS;R++) {
    for (int C=0;C<(NCOLS)-1;C++) {
      INDEX=(R*(NCOLS))+C;
      STICKA[P]=INDEX; STICKB[P]=INDEX+1;
      STICKLENGTH[P]=GAP;
      STICKPRESENT[P]=true;
        P++;
    }
  }  


//now vertical sticks
int BASE;
BASE=((NCOLS-1)*NROWS);
    for (int R=0;R<(NROWS-1);R++) {
    for (int C=0;C<NCOLS;C++) {
      INDEX=(R*NCOLS)+C;
      STICKA[INDEX+BASE]=INDEX; STICKB[INDEX+BASE]=INDEX+NCOLS;
      STICKLENGTH[INDEX+BASE]=GAP;
      STICKPRESENT[INDEX+BASE]=true;
      
    }
  } 

//attachment

  switch(PINMODE) {
  case 0: //l="Full";
   for (int i=0;i<NCOLS;i++) {PINNED[i]=true;}
   break;
  case 1: //l="Partial";
   for (int i=0;i<NCOLS;i+=8) {PINNED[i]=true;}
   break;
  case 2: //l="Sparse";
   for (int i=0;i<NCOLS;i+=16) {PINNED[i]=true;}
   break;
  case 3: //l="Corners";
   PINNED[0]=true;PINNED[NCOLS-1]=true;
   break;
  } 


RUNNING=false;

}


void renderbuttons() {
  textSize(16);
  textAlign(CENTER, CENTER);
  stroke(164,164,164);
  String label;
  
  if(RUNNING) {fill(128,110,0); label="RESET";} else {fill(100,100,100); label="Start";}
  rect(0,510,100,30,4);
  fill(255);
  text(label,50,525);
  
  if(DISP) {fill(128,110,0); label="Move";
        rect(0,550,100,30,4);
        fill(255);
        text(label,50,565);
 }
  else {fill(100,0,0); label="Cut";
  rect(0,550,100,30,4);
  fill(255);
  text(label,50,565);
}

  if(FULLSHEET) {fill(128,110,0); label="Full";
        rect(110,550,100,30,4);
        fill(255);
        text(label,160,565);
 }
  else {fill(100,0,0); label="Half";
  rect(110,550,100,30,4);
  fill(255);
  text(label,160,565);
}


 
 //pin
 String l;
 for (int i=0;i<=3;i++)
 {

  switch(i) {
  case 0: l="Full";break;
  case 1: l="Partial";break;
  case 2: l="Sparse";break;
  case 3: l="Corners";break;
  } 
 
  if (i==PINMODE) {fill(128,110,0);} else {fill(100,100,100);}
  rect(400+(i*90),510,80,30,4);
  fill(255);
  text(l,440+(i*90),525);
 }  
 

 
 //tear
  for (int i=0;i<=3;i++)
 {

  switch(i) {
  case 0: l="No tear";break;
  case 1: l="Strong";break;
  case 2: l="Medium";break;
  case 3: l="Weak";break;
  } 
 
  if (i==TEARMODE) {fill(128,110,0);} else {fill(100,100,100);}
  rect(400+(i*90),550,80,30,4);
  fill(255);
  text(l,440+(i*90),565);
 }  
 
  textSize(20);
  textAlign(RIGHT, CENTER);
  stroke(164,164,164);
  text("Rip Resistance: ",400,565);

  textAlign(RIGHT, CENTER);
  stroke(164,164,164);
  text("Attachment: ",400,525);
 

}

void mouseClicked() {
 if ( mouseY>=510 && mouseY<=540 && mouseX>0 && mouseX<100) {RUNNING=!RUNNING; if(!RUNNING) {reset();}}
 if ( mouseY>=550 && mouseY<=580 && mouseX>110 && mouseX<210) {FULLSHEET=!FULLSHEET; reset();}
 if ( mouseY>=540 && mouseY<=580 && mouseX>0 && mouseX<100) {DISP=!DISP;}
 if ( mouseY>=510 && mouseY<=540 && mouseX>400 && mouseX<750) {PINMODE=int((mouseX-400)/90); reset();}
 if ( mouseY>=550 && mouseY<=580 && mouseX>400 && mouseX<750) {TEARMODE=int((mouseX-400)/90); updatetearmode();}
}

void updatetearmode() {
  switch(TEARMODE) {
  case 0: RIPRATIO=99999;break;
  case 1: RIPRATIO=25;break;
  case 2: RIPRATIO=9;break;
  case 3: RIPRATIO=3.5;break;
  } 
 
}

void nickmousemove() {

    float dista;
  
    for(int i=0;i<N;i++)
     {
       dista=sqrt(((mouseX-PX[i])*(mouseX-PX[i]))+((mouseY-PY[i])*(mouseY-PY[i])));
       if (dista<=50 && PINNED[i]==false) {

    float dx,dy, dist, diff, percent, offx, offy;
  dx=PX[i]-mouseX;
  dy=PY[i]-mouseY;
  dist=sqrt((dx*dx)+(dy*dy));
  diff=5;
  percent=diff/dist;
  offx=dx*percent;
  offy=dy*percent;
  PX[i]+=offx;
  PY[i]+=offy;  
         
       } 
   
     }
  } 

void nickmousedelete() {

    float dista,cx,cy;
  
    for(int i=0;i<NS;i++) {
        if (STICKPRESENT[i]) {
         cx=(PX[STICKA[i]]+PX[STICKB[i]])/2;
         cy=(PY[STICKA[i]]+PY[STICKB[i]])/2;
       dista=sqrt(((mouseX-cx)*(mouseX-cx))+((mouseY-cy)*(mouseY-cy)));
       if (dista<=4) {STICKPRESENT[i]=false;}
             }
  } 
}