//  Discussion:
//
//    -uxx-uyy = f on the unit square.
//    u = g on the boundary.
//
//    f = - gxx - gyy
//    g = exp(-alpha*(x-xc)^2+(y-yc)^2)
//
//    Suggested parameter values:
//    * alpha = 1000,   (xc,yc) = (0.5,0.5)
//    * alpha = 100000, (xc,yc) = (0.51,0.117)
//
//  Location:
//
//    http://people.sc.fsu.edu/~jburkardt/freefem_src/mitchell_04/mitchell_04a.edp
//
//  Licensing:
//
//    This code is distributed under the MIT license.
//
//  Modified:
//
//    19 December 2014
//
//  Author:
//
//    John Burkardt
//
//  Reference:
//
//    Frederic Hecht,
//    Freefem++,
//    Third Edition, version 3.22
//
//    William Mitchell,
//    A collection of 2D elliptic problems for testing adaptive
//    grid refinement algorithms,
//    Applied Mathematics and Computation,
//    Volume 220, 1 September 2013, pages 350-364.
//
cout << "\n";
cout << "mitchell_04a\n";
cout << "  FreeFem++ version\n";
cout << "  The Peak problem\n";

border bottom ( t = 0.0, 1.0 )   { x = t;   y = 0.0;  label = 1; }
border right  ( t = 0.0, 1.0 )   { x = 1.0; y = t;    label = 1; }
border top    ( t = 1.0, 0.0 )   { x = t;   y = 1.0;  label = 1; }
border left   ( t = 1.0, 0.0 )   { x = 0.0; y = t;    label = 1; }
//
//  Define Th, the triangulation of the "left" side of the boundaries.
//
int n = 10;
mesh Th = buildmesh ( bottom ( n ) + right ( n ) + top ( n ) + left ( n ) );
//
//  Define Vh, the finite element space defined over Th, using P1 basis functions.
//
fespace Vh ( Th, P1 );
//
//  Define U, V, and F, piecewise continuous functions over Th.
//
Vh u;
Vh v;
//
//  Define problem parameters.
//
real xc = 0.5;
real yc = 0.5;
real alpha = 1000.0;
//
//  Define the right hand side function F.
//
func f = 4.0 * alpha * ( 1.0 - alpha * ( pow ( x - xc, 2 ) + pow ( y - yc, 2 ) ) )
  * exp ( - alpha * ( pow ( x - xc, 2 ) + pow ( y - yc, 2 ) ) );
//
//  Define the boundary function G.
//
func g = exp ( - alpha * ( pow ( x - xc, 2 ) + pow ( y - yc, 2 ) ) );
//
//  Solve the variational problem.
//
solve Laplace ( u, v ) 
  = int2d ( Th ) ( dx(u)*dx(v) + dy(u)*dy(v) )
  - int2d ( Th ) ( f * v ) 
  + on ( 1, u = g );
//
//  Plot the solution.
//
plot ( u, wait = true, fill = true, ps = "mitchell_04a_u.eps" );
//
//  Plot the mesh.
//
plot ( Th, wait = true, ps = "mitchell_04a_mesh.eps" );
//
//  Save the mesh file.
//
savemesh ( Th, "mitchell_04a.msh" );
//
//  Terminate.
//
cout << "\n";
cout << "mitchell_04a\n";
cout << "  Normal end of execution.\n";

exit ( 0 );