program main

!*****************************************************************************80
!
!! tsp_dantzig42_test() tests tsp_dantzig42().
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    26 July 2026
!
!  Author:
!
!    John Burkardt
!
  implicit none

  integer, parameter :: rk8 = kind ( 1.0D+00 )

  real ( kind = rk8 ) cost
  integer, allocatable :: dantzig42_order(:)
  real ( kind = rk8 ), allocatable :: dantzig42_xy(:,:)
  integer i
  integer i2
  integer, parameter :: n = 42
  real ( kind = rk8 ), allocatable :: x2(:,:)

  call timestamp ( )

  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'tsp_dantzig42_test():'
  write ( *, '(a)' ) '  Fortran90 version'
  write ( *, '(a)' ) '  Test tsp_dantzig42(), which returns the Dantzig 42 city'
  write ( *, '(a)' ) '  traveling salesperson problem challenge data.'

  allocate ( dantzig42_order(1:n) )
  call tsp_dantzig42_order ( dantzig42_order )
  allocate ( dantzig42_xy(1:n,1:2) )
  call tsp_dantzig42_xy ( dantzig42_xy )

  write ( *, '(a)' ) ''
  write ( *, '(a)' ) '  City coordinates:'
  write ( *, '(a)' ) ''
  do i = 1, n
    write ( *, '(2x,i2,2x,f8.1,2x,f8.1)' ) i, dantzig42_xy(i,1), dantzig42_xy(i,2)
  end do
!
!  Report the tour length.
!
  call tsp_tour_cost ( n, dantzig42_xy, dantzig42_order, cost )
  write ( *, '(a)' ) ''
  write ( *, '(a,g14.6)' ) '  Cost of round trip: ', cost
!
!  Copy the city locations in TSP order.
!
  allocate ( x2(n+1,2) )
 
  do i2 = 1, n + 1
    if ( i2 <= n ) then
      i = dantzig42_order(i2)
    else
      i = dantzig42_order(1)
    end if
    x2(i2,1) = dantzig42_xy(i,1)
    x2(i2,2) = dantzig42_xy(i,2)
  end do
!
!  Display the locations.
!
  call tsp_display ( "dantzig42", n + 1, x2 )
!
!  Free memory.
!
  deallocate ( dantzig42_order )
  deallocate ( dantzig42_xy )
  deallocate ( x2 )
!
!  Terminate.
!
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'tsp_dantzig42_test():'
  write ( *, '(a)' ) '  Normal end of execution.'

  call timestamp ( )

  stop
end
subroutine tsp_display ( prefix, n, x2 )

!*****************************************************************************80
!
!! tsp_display() plots cities and a tour connecting them.
!
!  Discussion:
!
!    If a "round trip" is desired, then the x2 array must repeat the
!    first city at the end.
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    12 June 2026
!
!  Author:
!
!    John Burkardt
!
!  Input:
!
!    character ( len = * ) prefix: a string that defines the name of
!    the problem.  It is also used to create file names needed for
!    input to gnuplot.
!
!    integer n: the number of cities.
!
!    real ( kind = rk8 ) x(n,2): the x and y coordinates of the cities.
!
  implicit none

  integer, parameter :: rk8 = kind ( 1.0D+00 )
  integer n

  character ( len = 80 ) command_filename
  integer command_unit
  character ( len = 80 ) data_filename
  integer data_unit
  integer i
  character ( len = * ) prefix
  real ( kind = rk8 ) x2(n,2)
!
!  Create the data file.
!
  call get_unit ( data_unit )
  data_filename = prefix // '_data.txt'
  open ( unit = data_unit, file = data_filename, status = 'replace' )
  do i = 1, n
    write ( data_unit, '(2x,g14.6,2x,g14.6)' ) x2(i,1), x2(i,2)
  end do
  close ( unit = data_unit )
  write ( *, '(a)' ) '  Created data file "' // trim ( data_filename ) // '".'
!
!  Create command file.
!
  call get_unit ( command_unit )
  command_filename = prefix // '_commands.txt'
  open ( unit = command_unit, file = command_filename, status = 'replace' )
  write ( command_unit, '(a)' ) '# ' // trim ( command_filename )
  write ( command_unit, '(a)' ) '#'
  write ( command_unit, '(a)' ) '# Usage:'
  write ( command_unit, '(a)' ) '#  gnuplot < ' // trim ( command_filename )
  write ( command_unit, '(a)' ) '#'
  write ( command_unit, '(a)' ) 'set term png'
  write ( command_unit, '(a)' ) 'set output "' // prefix // '.png"'
  write ( command_unit, '(a)' ) 'set xlabel "<-- X -->"'
  write ( command_unit, '(a)' ) 'set ylabel "<-- Y -->"'
  write ( command_unit, '(a)' ) 'set title "' // prefix // '"'
  write ( command_unit, '(a)' ) 'set grid'
  write ( command_unit, '(a)' ) 'unset key'
  write ( command_unit, '(a)' ) 'set style data lines'
  write ( command_unit, '(a)' ) 'plot "' // trim ( data_filename ) // &
    '" using 1:2 lw 3 linecolor rgb "blue", \'
  write ( command_unit, '(a)' ) '     "' // trim ( data_filename ) // &
    '" using 1:2 with points pointtype 7 pointsize 3 linecolor rgb "green"'
  write ( command_unit, '(a)' ) 'quit'
  close ( unit = command_unit )
  write ( *, '(a)' ) &
    '  Created command file "' // trim ( command_filename ) // '".'

  return
end
subroutine tsp_tour_cost ( n, x, order, cost )

!*****************************************************************************80
!
!! tsp_tour_cost() evaluates the cost of a round trip.
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    19 June 2026
!
!  Author:
!
!    John Burkardt
!
!  Input:
!
!    integer n: the number of cities.
!
!    real x(n,2): the city locations.
!
!    integer order(n): a permutation of 1:N, the route.
!
!  Output:
!
!    real cost: the cost of the route.
!
  implicit none

  integer, parameter :: rk8 = kind ( 1.0D+00 )

  integer n

  real ( kind = rk8 ) cost
  integer from
  integer order(n)
  integer to
  real ( kind = rk8 ) x(n,2)

  cost = 0.0D+00
  from = n
  do to = 1, n
    cost = cost + sqrt ( ( x(order(from),1) - x(order(to),1) )**2 &
                       + ( x(order(from),2) - x(order(to),2) )**2 )
    from = to
  end do

  return
end
subroutine get_unit ( iunit )

!*****************************************************************************80
!
!! get_unit() returns a free Fortran unit number.
!
!  Discussion:
!
!    A "free" Fortran unit number is a value between 1 and 99 which
!    is not currently associated with an I/O device.  A free Fortran unit
!    number is needed in order to open a file with the OPEN command.
!
!    If IUNIT = 0, then no free Fortran unit could be found, although
!    all 99 units were checked (except for units 5, 6 and 9, which
!    are commonly reserved for console I/O).
!
!    Otherwise, IUNIT is a value between 1 and 99, representing a
!    free Fortran unit.  Note that GET_UNIT assumes that units 5 and 6
!    are special, and will never return those values.
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    26 October 2008
!
!  Author:
!
!    John Burkardt
!
!  Output:
!
!    integer IUNIT, the free unit number.
!
  implicit none

  integer i
  integer ios
  integer iunit
  logical lopen

  iunit = 0

  do i = 1, 99

    if ( i /= 5 .and. i /= 6 .and. i /= 9 ) then

      inquire ( unit = i, opened = lopen, iostat = ios )

      if ( ios == 0 ) then
        if ( .not. lopen ) then
          iunit = i
          return
        end if
      end if

    end if

  end do

  return
end
subroutine timestamp ( )

!*****************************************************************************80
!
!! timestamp() prints the current YMDHMS date as a time stamp.
!
!  Example:
!
!    31 May 2001   9:45:54.872 AM
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    15 August 2021
!
!  Author:
!
!    John Burkardt
!
  implicit none

  character ( len = 8 ) ampm
  integer d
  integer h
  integer m
  integer mm
  character ( len = 9 ), parameter, dimension(12) :: month = (/ &
    'January  ', 'February ', 'March    ', 'April    ', &
    'May      ', 'June     ', 'July     ', 'August   ', &
    'September', 'October  ', 'November ', 'December ' /)
  integer n
  integer s
  integer values(8)
  integer y

  call date_and_time ( values = values )

  y = values(1)
  m = values(2)
  d = values(3)
  h = values(5)
  n = values(6)
  s = values(7)
  mm = values(8)

  if ( h < 12 ) then
    ampm = 'AM'
  else if ( h == 12 ) then
    if ( n == 0 .and. s == 0 ) then
      ampm = 'Noon'
    else
      ampm = 'PM'
    end if
  else
    h = h - 12
    if ( h < 12 ) then
      ampm = 'PM'
    else if ( h == 12 ) then
      if ( n == 0 .and. s == 0 ) then
        ampm = 'Midnight'
      else
        ampm = 'AM'
      end if
    end if
  end if

  write ( *, '(i2.2,1x,a,1x,i4,2x,i2,a1,i2.2,a1,i2.2,a1,i3.3,1x,a)' ) &
    d, trim ( month(m) ), y, h, ':', n, ':', s, '.', mm, trim ( ampm )

  return
end