function harmonic_number ( n )

!*****************************************************************************80
!
!! harmonic_number() computes the Nth harmonic number.
!
!  Discussion:
!
!    H(N) = Sum ( 1 <= I <= N ) 1 / I
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    21 May 2022
!
!  Author:
!
!    John Burkardt
!
!  Input:
!
!    integer N: the index of the harmonic number.
!
!  Output:
!
!    real VALUE: the value of the harmonic number.
!
  implicit none

  integer, parameter :: rk8 = kind ( 1.0D+00 )

  real ( kind = rk8 ) harmonic_number
  integer i
  integer n
  real ( kind = rk8 ) value

  value = 0.0D+00

  do i = 1, n
    value = value + 1.0D+00 / i
  end do

  harmonic_number = value

  return
end
function steinerberger_function ( n, x )

!*****************************************************************************80
!
!! steinerberger_function() evaluates the Steinerberger function.
!
!  Discussion:
!
!    f(n,x) = sum ( 1 <= k <= n ) abs ( sin ( pi * k * x ) ) / k
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    29 March 2025
!
!  Author:
!
!    John Burkardt
!
!  Reference:
!
!    John D Cook,
!    Pushing numerical integration software to its limits,
!    https://www.johndcook.com/blog/2023/06/12/stressing-numerical-integration/
!    Posted 12 June 2023.
!
!    John D Cook,
!    Plotting a function with lots of local minima,
!    https://www.johndcook.com/blog/2023/06/12/lots-of-local-minima/
!    Posted 12 June 2023.
!
!    Stefan Steinerberger,
!    A amusing sequence of functions,
!    Mathematics Magazine,
!    Volume 91, Number 4, October 2018, pages 262-266.
!
!  Input:
!
!    integer N: the index of the function.
!
!    real X: the evaluation point.
!
!  Output:
!
!    real VALUE: the function value.
!
  implicit none

  integer, parameter :: rk8 = kind ( 1.0D+00 )

  integer k
  integer n
  real ( kind = rk8 ), parameter :: r8_pi = 3.141592653589793D+00
  real ( kind = rk8 ) steinerberger_function
  real ( kind = rk8 ) value
  real ( kind = rk8 ) x

  value = 0.0D+00
  do k = 1, n
    value = value + abs ( sin ( k * r8_pi * x ) ) / k
  end do

  steinerberger_function = value

  return
end
function steinerberger_integral01 ( n )

!*****************************************************************************80
!
!! steinerberger_integral01() returns the Steinerberger integral from 0 to 1.
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    29 March 2025
!
!  Author:
!
!    John Burkardt
!
!  Reference:
!
!    John D Cook,
!    Pushing numerical integration software to its limits,
!    https://www.johndcook.com/blog/2023/06/12/stressing-numerical-integration/
!    Posted 12 June 2023.
!
!    John D Cook,
!    Plotting a function with lots of local minima,
!    https://www.johndcook.com/blog/2023/06/12/lots-of-local-minima/
!    Posted 12 June 2023.
!
!    Stefan Steinerberger,
!    A amusing sequence of functions,
!    Mathematics Magazine,
!    Volume 91, Number 4, October 2018, pages 262-266.
!
!  Input:
!
!    integer N: the index of the function.
!
!  Output:
!
!    real VALUE: the value of the integral from 0 to 1.
!
  implicit none

  integer, parameter :: rk8 = kind ( 1.0D+00 )

  real ( kind = rk8 ) harmonic_number
  integer n
  real ( kind = rk8 ), parameter :: r8_pi = 3.141592653589793D+00
  real ( kind = rk8 ) steinerberger_integral01

  steinerberger_integral01 = 2.0D+00 * harmonic_number ( n ) / r8_pi

  return
end