program main

!*****************************************************************************80
!
!! minimal_surface_exact_test() tests minimal_surface_exact().
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    01 June 2025
!
!  Author:
!
!    John Burkardt
!
  implicit none

  integer, parameter :: rk8 = kind ( 1.0D+00 )

  integer, parameter :: n = 5

  real ( kind = rk8 ) a
  real ( kind = rk8 ) b
  real ( kind = rk8 ) c
  real ( kind = rk8 ) R(n)
  real ( kind = rk8 ) r8vec_norm_rms
  real ( kind = rk8 ) X(n)
  real ( kind = rk8 ) X1(n)
  real ( kind = rk8 ) Y(n)
  real ( kind = rk8 ) Y1(n)

  call timestamp ( )

  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'minimal_surface_exact_test():'
  write ( *, '(a)' ) '  Fortran90 version.'
  write ( *, '(a)' ) '  Test minimal_surface_exact().'

  call random_number ( harvest = X(1:n) )
  call random_number ( harvest = Y(1:n) )
  a = 1.0D+00
  b = 2.0D+00
  c = 3.0D+00
!
!  Linear solution.
!
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) '  Linear solution residual at random points:'

  call minimal_surface_linear_residual ( n, X, Y, a, b, c, R )

  write ( *, '(a,g14.6)' ) '  RMS residual norm = ', r8vec_norm_rms ( n, R )
!
!  Helicoid solution.
!
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) '  Helicoid solution residual at random points:'

  call minimal_surface_helicoid_residual ( n, X, Y, R )

  write ( *, '(a,g14.6)' ) '  RMS residual norm = ', r8vec_norm_rms ( n, R )
!
!  Catenoid solution.
!
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) '  Catenoid solution residual at random points:'

  X1(1:n) = X(1:n) + 1.0D+00
  Y1(1:n) = Y(1:n) + 1.0D+00
  call minimal_surface_catenoid_residual ( n, X1, Y1, a, R )

  write ( *, '(a,g14.6)' ) '  RMS residual norm = ', r8vec_norm_rms ( n, R )
!
!  Scherk solution.
!
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) '  Scherk solution residual at random points:'

  call minimal_surface_scherk_residual ( n, X, Y, a, R )

  write ( *, '(a,g14.6)' ) '  RMS residual norm = ', r8vec_norm_rms ( n, R )
!
!  Terminate.
!
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'minimal_surface_exact_test()'
  write ( *, '(a)' ) '  Normal end of execution.'
  write ( *, '(a)' ) ''
  call timestamp ( )

  return
end
function r8vec_norm_rms ( n, a )

!*****************************************************************************80
!
!! r8vec_norm_rms() returns the RMS norm of an R8VEC.
!
!  Discussion:
!
!    An R8VEC is a vector of R8's.
!
!    The vector RMS norm is defined as:
!
!      R8VEC_NORM_RMS = sqrt ( sum ( 1 <= I <= N ) A(I)^2 / N ).
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    26 October 2011
!
!  Author:
!
!    John Burkardt
!
!  Input:
!
!    integer N, the number of entries in A.
!
!    real ( kind = rk8 ) A(N), the vector.
!
!  Output:
!
!    real ( kind = rk8 ) R8VEC_NORM_RMS, the RMS norm of A.
!
  implicit none

  integer, parameter :: rk8 = kind ( 1.0D+00 )

  integer n

  real ( kind = rk8 ) a(n)
  real ( kind = rk8 ) r8vec_norm_rms

  r8vec_norm_rms = sqrt ( sum ( a(1:n) ** 2 ) / real ( n, kind = rk8 ) )

  return
end
subroutine timestamp ( )

!*****************************************************************************80
!
!! timestamp() prints the current YMDHMS date as a time stamp.
!
!  Example:
!
!    31 May 2001   9:45:54.872 AM
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    15 August 2021
!
!  Author:
!
!    John Burkardt
!
  implicit none

  character ( len = 8 ) ampm
  integer d
  integer h
  integer m
  integer mm
  character ( len = 9 ), parameter, dimension(12) :: month = (/ &
    'January  ', 'February ', 'March    ', 'April    ', &
    'May      ', 'June     ', 'July     ', 'August   ', &
    'September', 'October  ', 'November ', 'December ' /)
  integer n
  integer s
  integer values(8)
  integer y

  call date_and_time ( values = values )

  y = values(1)
  m = values(2)
  d = values(3)
  h = values(5)
  n = values(6)
  s = values(7)
  mm = values(8)

  if ( h < 12 ) then
    ampm = 'AM'
  else if ( h == 12 ) then
    if ( n == 0 .and. s == 0 ) then
      ampm = 'Noon'
    else
      ampm = 'PM'
    end if
  else
    h = h - 12
    if ( h < 12 ) then
      ampm = 'PM'
    else if ( h == 12 ) then
      if ( n == 0 .and. s == 0 ) then
        ampm = 'Midnight'
      else
        ampm = 'AM'
      end if
    end if
  end if

  write ( *, '(i2.2,1x,a,1x,i4,2x,i2,a1,i2.2,a1,i2.2,a1,i3.3,1x,a)' ) &
    d, trim ( month(m) ), y, h, ':', n, ':', s, '.', mm, trim ( ampm )

  return
end