program main

!*****************************************************************************80
!
!! hankel_cholesky_test() tests hankel_cholesky().
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    29 January 2017
!
!  Author:
!
!    John Burkardt
!
  implicit none

  call timestamp ( )
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'hankel_cholesky_test():'
  write ( *, '(a)' ) '  FORTRAN90 version'
  write ( *, '(a)' ) '  Test hankel_cholesky().'

  call hankel_cholesky_upper_test ( )
!
!  Terminate.
!
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'hankel_cholesky_test():'
  write ( *, '(a)' ) '  Normal end of execution.'
  write ( *, '(a)' ) ''
  call timestamp ( )

  stop 0
end
subroutine hankel_cholesky_upper_test ( )

!*****************************************************************************80
!
!! HANKEL_CHOLESKY_UPPER_TEST tests HANKEL_CHOLESKY_UPPER.
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    29 January 2017
!
!  Author:
!
!    John Burkardt
!
  implicit none

  integer, parameter :: rk = kind ( 1.0D+00 )

  integer, parameter :: n = 5

  integer flag
  real ( kind = rk ) h(n,n)
  real ( kind = rk ) hanti(2*n-1)
  real ( kind = rk ) l(n,n)
  real ( kind = rk ) lii(n)
  real ( kind = rk ) liim1(n-1)
  real ( kind = rk ) r1(n,n)
  real ( kind = rk ) r2(n,n)

  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'hankel_cholesky_upper_test():'
  write ( *, '(a)' ) '  hankel_cholesky_upper() is given a Hankel matrix H and'
  write ( *, '(a)' ) '  computes an upper triangular matrix R such that'
  write ( *, '(a)' ) '  H = R'' * R'
!
!  Get a Hankel matrix that is positive definite.
!
  call random_number ( harvest = lii(1:n) )
  call random_number ( harvest = liim1(1:n-1) )
  call hankel_pds_cholesky_lower ( n, lii, liim1, l )
  h = matmul ( l, transpose ( l ) )
  call r8mat_print ( n, n, h, '  The Hankel matrix H:' )
!
!  Compute R using R8MAT_CHOLESKY_FACTOR_UPPER.
!
  call r8mat_cholesky_factor_upper ( n, h, r1, flag )
  if ( flag /= 0 ) then
    write ( *, '(a)' ) ''
    write ( *, '(a)' ) ' r8mat_cholesky_factor_upper() says H is not positive definite.'
  else
    call r8mat_print ( n, n, r1, '  R computed by R8MAT_CHOLESKY_FACTOR_UPPER:' )
  end if
!
!  Compute R using HANKEL_CHOLESKY.
!
  hanti(1:n) = h(1:n,1)
  hanti(n+1:2*n-1) = h(n,2:n)

  call hankel_cholesky_upper ( n, hanti, r2 )
  call r8mat_print ( n, n, r2, '  R computed by HANKEL_CHOLESKY:' )

  return
end
subroutine timestamp ( )

!*****************************************************************************80
!
!! timestamp() prints the current YMDHMS date as a time stamp.
!
!  Example:
!
!    31 May 2001   9:45:54.872 AM
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    18 May 2013
!
!  Author:
!
!    John Burkardt
!
  implicit none

  character ( len = 8 ) ampm
  integer d
  integer h
  integer m
  integer mm
  character ( len = 9 ), parameter, dimension(12) :: month = (/ &
    'January  ', 'February ', 'March    ', 'April    ', &
    'May      ', 'June     ', 'July     ', 'August   ', &
    'September', 'October  ', 'November ', 'December ' /)
  integer n
  integer s
  integer values(8)
  integer y

  call date_and_time ( values = values )

  y = values(1)
  m = values(2)
  d = values(3)
  h = values(5)
  n = values(6)
  s = values(7)
  mm = values(8)

  if ( h < 12 ) then
    ampm = 'AM'
  else if ( h == 12 ) then
    if ( n == 0 .and. s == 0 ) then
      ampm = 'Noon'
    else
      ampm = 'PM'
    end if
  else
    h = h - 12
    if ( h < 12 ) then
      ampm = 'PM'
    else if ( h == 12 ) then
      if ( n == 0 .and. s == 0 ) then
        ampm = 'Midnight'
      else
        ampm = 'AM'
      end if
    end if
  end if

  write ( *, '(i2,1x,a,1x,i4,2x,i2,a1,i2.2,a1,i2.2,a1,i3.3,1x,a)' ) &
    d, trim ( month(m) ), y, h, ':', n, ':', s, '.', mm, trim ( ampm )

  return
end