program main

c*********************************************************************72
c
cc tsp_brute_test() tests tsp_brute().
c
c  Licensing:
c
c    This code is distributed under the MIT license.
c
c  Modified:
c
c    16 August 2026
c
c  Author:
c
c    John Burkardt
c
      implicit none

      integer, parameter :: rk8 = kind ( 1.0D+00 )

      integer, parameter :: n = 12

      real ( kind = rk8 ) cost
      integer i
      integer i2
      integer order(n)
      character*(5) :: prefix = "att12"
c
c  This looks like a nx2 array, but Fortran will store it as 2xnc
c
      real ( kind = rk8 ), save, dimension ( n, 2 ) :: 
     &  x = transpose ( reshape ( (/ 
     &  6734, 1453, 
     &  2233,   10, 
     &  5530, 1424, 
     &   401,  841, 
     &  3082, 1644, 
     &  7608, 4458, 
     &  7573, 3716, 
     &  7265, 1268, 
     &  6898, 1885, 
     &  1112, 2049, 
     &  5468, 2606, 
     &  5989, 2873 /), (/ 2, n /) ) )
      real ( kind = rk8 ), allocatable :: x2(:,:)

      call timestamp ( )
      write ( *, '(a)' ) ''
      write ( *, '(a)' ) 'tsp_brute_test()'
      write ( *, '(a)' ) '  Fortran90 version'
      write ( *, '(a)' ) '  tsp_brute() solves a traveling salesman'
      write ( *, '(a)' ) '  problem (TSP) using brute force.'
c
c  Get the solution.
c
      call tsp_brute ( n, x, cost, order )

      write ( *, '(a,g14.6)' ) '  Length of optimal path is ', cost
c
c  Create the circuit data .
c
      allocate ( x2 ( 1 : n, 1 : 2 ) )

      do i = 1, n
        i2 = order(i)
        x2(i,1:2) = x(i2,1:2)
      end do
c
c  Send the data to the plotter.
c
      call tsp_display ( prefix, n, x2 )

      deallocate ( x2 )
c
c  Terminate.
c
      write ( *, '(a)' ) ''
      write ( *, '(a)' ) 'tsp_brute_test():'
      write ( *, '(a)' ) '  Normal end of execution.'

      call timestamp ( )
 
      stop
      end
      subroutine tsp_display ( prefix, n, x2 )

c*********************************************************************72
c
cc tsp_display() plots cities and a tour connecting them.
c
c  Discussion:
c
c    The code automatically adds a final stop at the initial city.
c
c  Licensing:
c
c    This code is distributed under the MIT license.
c
c  Modified:
c
c    27 July 2026
c
c  Author:
c
c    John Burkardt
c
c  Input:
c
c    character ( len = * ) prefix: a string that defines the name of
c    the problem.  It is also used to create file names needed for
c    input to gnuplot.
c
c    integer n: the number of cities.
c
c    double precision x(n,2): the x and y coordinates of the cities.
c
      implicit none

      integer n

      character ( len = 80 ) command_filename
      integer command_unit
      character ( len = 80 ) data_filename
      integer data_unit
      integer i
      character ( len = * ) prefix
      double precision x2(n,2)
c
c  Create the data file.
c
      call get_unit ( data_unit )
      data_filename = prefix // '_data.txt'
      open ( unit = data_unit, file = data_filename, 
     &  status = 'replace' )
      do i = 1, n
        write ( data_unit, '(2x,g14.6,2x,g14.6)' ) x2(i,1), x2(i,2)
      end do
      i = 1
      write ( data_unit, '(2x,g14.6,2x,g14.6)' ) x2(i,1), x2(i,2)
      close ( unit = data_unit )
      write ( *, '(a)' ) '  Created data file "' 
     &  // trim ( data_filename ) // '".'
c
c  Create command file.
c
      call get_unit ( command_unit )
      command_filename = prefix // '_commands.txt'
      open ( unit = command_unit, file = command_filename, 
     &  status = 'replace' )
      write ( command_unit, '(a)' ) '# ' // trim ( command_filename )
      write ( command_unit, '(a)' ) '#'
      write ( command_unit, '(a)' ) '# Usage:'
      write ( command_unit, '(a)' ) '#  gnuplot < ' 
     &  // trim ( command_filename )
      write ( command_unit, '(a)' ) '#'
      write ( command_unit, '(a)' ) 'set term png'
      write ( command_unit, '(a)' ) 'set output "' // prefix // '.png"'
      write ( command_unit, '(a)' ) 'set xlabel "<-- X -->"'
      write ( command_unit, '(a)' ) 'set ylabel "<-- Y -->"'
      write ( command_unit, '(a)' ) 'set title "' // prefix // '"'
      write ( command_unit, '(a)' ) 'set grid'
      write ( command_unit, '(a)' ) 'unset key'
      write ( command_unit, '(a)' ) 'set style data lines'
      write ( command_unit, '(a)' ) 'plot "' 
     &  // trim ( data_filename ) // 
     &  '" using 1:2 lw 3 linecolor rgb "blue", \'
      write ( command_unit, '(a)' ) '     "' 
     &  // trim ( data_filename ) // 
     &  '" using 1:2 with points pt 7 ps 3 linecolor rgb "green"'
      write ( command_unit, '(a)' ) 'quit'
      close ( unit = command_unit )
      write ( *, '(a)' ) 
     &  '  Created command file "' // trim ( command_filename ) // '".'

      return
      end
      subroutine get_unit ( iunit )

c*********************************************************************72
c
cc get_unit() returns a free Fortran unit number.
c
c  Discussion:
c
c    A "free" Fortran unit number is a value between 1 and 99 which
c    is not currently associated with an I/O device.  A free Fortran unit
c    number is needed in order to open a file with the OPEN command.
c
c    If IUNIT = 0, then no free Fortran unit could be found, although
c    all 99 units were checked (except for units 5, 6 and 9, which
c    are commonly reserved for console I/O).
c
c    Otherwise, IUNIT is a value between 1 and 99, representing a
c    free Fortran unit.  Note that GET_UNIT assumes that units 5 and 6
c    are special, and will never return those values.
c
c  Licensing:
c
c    This code is distributed under the MIT license.
c
c  Modified:
c
c    26 October 2008
c
c  Author:
c
c    John Burkardt
c
c  Output:
c
c    integer IUNIT, the free unit number.
c
      implicit none

      integer i
      integer ios
      integer iunit
      logical lopen

      iunit = 0

      do i = 1, 99

        if ( i /= 5 .and. i /= 6 .and. i /= 9 ) then

          inquire ( unit = i, opened = lopen, iostat = ios )

          if ( ios == 0 ) then
            if ( .not. lopen ) then
              iunit = i
              return
            end if
          end if

        end if

      end do

      return
      end

      subroutine timestamp ( )

c*********************************************************************72
c
cc timestamp() prints the YMDHMS date as a timestamp.
c
c  Licensing:
c
c    This code is distributed under the MIT license.
c
c  Modified:
c
c    12 June 2014
c
c  Author:
c
c    John Burkardt
c
      implicit none

      character * ( 8 ) ampm
      integer d
      character * ( 8 ) date
      integer h
      integer m
      integer mm
      character * ( 9 ) month(12)
      integer n
      integer s
      character * ( 10 ) time
      integer y

      save month

      data month /
     &  'January  ', 'February ', 'March    ', 'April    ', 
     &  'May      ', 'June     ', 'July     ', 'August   ', 
     &  'September', 'October  ', 'November ', 'December ' /

      call date_and_time ( date, time )

      read ( date, '(i4,i2,i2)' ) y, m, d
      read ( time, '(i2,i2,i2,1x,i3)' ) h, n, s, mm

      if ( h .lt. 12 ) then
        ampm = 'AM'
      else if ( h .eq. 12 ) then
        if ( n .eq. 0 .and. s .eq. 0 ) then
          ampm = 'Noon'
        else
          ampm = 'PM'
        end if
      else
        h = h - 12
        if ( h .lt. 12 ) then
          ampm = 'PM'
        else if ( h .eq. 12 ) then
          if ( n .eq. 0 .and. s .eq. 0 ) then
            ampm = 'Midnight'
          else
            ampm = 'AM'
          end if
        end if
      end if

      write ( *, 
     &  '(i2,1x,a,1x,i4,2x,i2,a1,i2.2,a1,i2.2,a1,i3.3,1x,a)' ) 
     &  d, trim ( month(m) ), y, h, ':', n, ':', s, '.', mm, 
     &  trim ( ampm )

      return
      end