function harmonic_number ( n )

c*********************************************************************72
c
cc harmonic_number() computes the Nth harmonic number.
c
c  Discussion:
c
c    H(N) = Sum ( 1 <= I <= N ) 1 / I
c
c  Licensing:
c
c    This code is distributed under the MIT license.
c
c  Modified:
c
c    29 March 2025
c
c  Author:
c
c    John Burkardt
c
c  Input:
c
c    integer N: the index of the harmonic number.
c
c  Output:
c
c    real VALUE: the value of the harmonic number.
c
      implicit none

      double precision harmonic_number
      integer i
      integer n
      double precision value

      value = 0.0D+00

      do i = 1, n
        value = value + 1.0D+00 / i
      end do

      harmonic_number = value

      return
      end
      function steinerberger_function ( n, x )

c*********************************************************************72
c
cc steinerberger_function() evaluates the Steinerberger function.
c
c  Discussion:
c
c    f(n,x) = sum ( 1 <= k <= n ) abs ( sin ( pi * k * x ) ) / k
c
c  Licensing:
c
c    This code is distributed under the MIT license.
c
c  Modified:
c
c    29 March 2025
c
c  Author:
c
c    John Burkardt
c
c  Reference:
c
c    John D Cook,
c    Pushing numerical integration software to its limits,
c    https://www.johndcook.com/blog/2023/06/12/stressing-numerical-integration/
c    Posted 12 June 2023.
c
c    John D Cook,
c    Plotting a function with lots of local minima,
c    https://www.johndcook.com/blog/2023/06/12/lots-of-local-minima/
c    Posted 12 June 2023.
c
c    Stefan Steinerberger,
c    A amusing sequence of functions,
c    Mathematics Magazine,
c    Volume 91, Number 4, October 2018, pages 262-266.
c
c  Input:
c
c    integer N: the index of the function.
c
c    real X: the evaluation point.
c
c  Output:
c
c    real VALUE: the function value.
c
      implicit none

      integer k
      integer n
      double precision, parameter :: r8_pi = 3.141592653589793D+00
      double precision steinerberger_function
      double precision value
      double precision x

      value = 0.0D+00
      do k = 1, n
        value = value + abs ( sin ( k * r8_pi * x ) ) / k
      end do

      steinerberger_function = value

      return
      end
      function steinerberger_integral01 ( n )

c*********************************************************************72
c
cc steinerberger_integral01() returns the Steinerberger integral from 0 to 1.
c
c  Licensing:
c
c    This code is distributed under the MIT license.
c
c  Modified:
c
c    29 March 2025
c
c  Author:
c
c    John Burkardt
c
c  Reference:
c
c    John D Cook,
c    Pushing numerical integration software to its limits,
c    https://www.johndcook.com/blog/2023/06/12/stressing-numerical-integration/
c    Posted 12 June 2023.
c
c    John D Cook,
c    Plotting a function with lots of local minima,
c    https://www.johndcook.com/blog/2023/06/12/lots-of-local-minima/
c    Posted 12 June 2023.
c
c    Stefan Steinerberger,
c    A amusing sequence of functions,
c    Mathematics Magazine,
c    Volume 91, Number 4, October 2018, pages 262-266.
c
c  Input:
c
c    integer N: the index of the function.
c
c  Output:
c
c    real VALUE: the value of the integral from 0 to 1.
c
      implicit none

      double precision harmonic_number
      integer n
      double precision, parameter :: r8_pi = 3.141592653589793D+00
      double precision steinerberger_integral01

      steinerberger_integral01 = 2.0D+00 * harmonic_number ( n ) / r8_pi

      return
      end