program main

!*****************************************************************************80
!
!! satisfy_brute_test() tests satisfy_brute().
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    27 October 2022
!
!  Author:
!
!    John Burkardt
!
  implicit none

  call timestamp ( )
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'satisfy_brute_test():'
  write ( *, '(a)' ) '  Fortran90 version'
  write ( *, '(a)' ) '  Test satisfy_brute().'

  call satisfy_brute_test01 ( )
!
!  Terminate.
!
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'satisfy_brute_test():'
  write ( *, '(a)' ) '  Normal end of execution.'
  write ( *, '(a)' ) ''
  call timestamp ( );

  return
end
subroutine satisfy_brute_test01 ( )

!*****************************************************************************80
!
!! satisfy_brute_test01() tests satisfy_brute().
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    27 October 2022
!
!  Author:
!
!    John Burkardt
!
  implicit none

  integer, external :: formula_01
  integer n

  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'satisfy_brute_test01():'
  write ( *, '(a)' ) '  satisfy_brute() seeks values of logical'
  write ( *, '(a)' ) '  variables that make a given formula true'

  n = 23

  call satisfy_brute ( n, formula_01 )

  return
end
function formula_01 ( bvec )

!*****************************************************************************80
!
!! formula_01() returns the value of a circuit for a given input set.
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    20 March 2009
!
!  Author:
!
!    John Burkardt
!
!  Reference:
!
!    Michael Quinn,
!    Parallel Programming in C with MPI and OpenMP,
!    McGraw-Hill, 2004,
!    ISBN13: 978-0071232654,
!    LC: QA76.73.C15.Q55.
!
!  Input:
!
!    integer BVEC(N), the binary inputs.
!
!  Output:
!
!    integer formula_01: the output of the circuit.
!
  implicit none

  integer bvec(*)
  integer formula_01
  logical value

  value = ( bvec(1)  == 1 .or. bvec(2)  == 1 ) &
    .and. ( bvec(2)  == 0 .or. bvec(4)  == 0 ) &
    .and. ( bvec(3)  == 1 .or. bvec(4)  == 1 ) &
    .and. ( bvec(4)  == 0 .or. bvec(5)  == 0 ) &
    .and. ( bvec(5)  == 1 .or. bvec(6)  == 0 ) &
    .and. ( bvec(6)  == 1 .or. bvec(7)  == 0 ) &
    .and. ( bvec(6)  == 1 .or. bvec(7)  == 1 ) &
    .and. ( bvec(7)  == 1 .or. bvec(16) == 0 ) &
    .and. ( bvec(8)  == 1 .or. bvec(9)  == 0 ) &
    .and. ( bvec(8)  == 0 .or. bvec(14) == 0 ) &
    .and. ( bvec(9)  == 1 .or. bvec(10) == 1 ) &
    .and. ( bvec(9)  == 1 .or. bvec(10) == 0 ) &
    .and. ( bvec(10) == 0 .or. bvec(11) == 0 ) &
    .and. ( bvec(10) == 1 .or. bvec(12) == 1 ) &
    .and. ( bvec(11) == 1 .or. bvec(12) == 1 ) &
    .and. ( bvec(13) == 1 .or. bvec(14) == 1 ) &
    .and. ( bvec(14) == 1 .or. bvec(15) == 0 ) &
    .and. ( bvec(15) == 1 .or. bvec(16) == 1 ) &
    .and. ( bvec(15) == 1 .or. bvec(17) == 1 ) &
    .and. ( bvec(18) == 1 .or. bvec(2)  == 1 ) &
    .and. ( bvec(19) == 1 .or. bvec(1)  == 0 ) &
    .and. ( bvec(20) == 1 .or. bvec(2)  == 1 ) &
    .and. ( bvec(20) == 1 .or. bvec(19) == 0 ) &
    .and. ( bvec(20) == 0 .or. bvec(10) == 0 ) &
    .and. ( bvec(1)  == 1 .or. bvec(18) == 1 ) &
    .and. ( bvec(2)  == 0 .or. bvec(21) == 1 ) &
    .and. ( bvec(22) == 0 .or. bvec(21) == 1 ) &
    .and. ( bvec(23) == 0 .or. bvec(21) == 1 ) &
    .and. ( bvec(22) == 0 .or. bvec(21) == 0 ) &
    .and. ( bvec(23) == 1 .or. bvec(21) == 0 )

  if ( value ) then
    formula_01 = 1
  else
    formula_01 = 0
  end if

  return
end
subroutine timestamp ( )

!*****************************************************************************80
!
!! timestamp() prints the current YMDHMS date as a time stamp.
!
!  Example:
!
!    31 May 2001   9:45:54.872 AM
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    18 May 2013
!
!  Author:
!
!    John Burkardt
!
  implicit none

  character ( len = 8 ) ampm
  integer d
  integer h
  integer m
  integer mm
  character ( len = 9 ), parameter, dimension(12) :: month = (/ &
    'January  ', 'February ', 'March    ', 'April    ', &
    'May      ', 'June     ', 'July     ', 'August   ', &
    'September', 'October  ', 'November ', 'December ' /)
  integer n
  integer s
  integer values(8)
  integer y

  call date_and_time ( values = values )

  y = values(1)
  m = values(2)
  d = values(3)
  h = values(5)
  n = values(6)
  s = values(7)
  mm = values(8)

  if ( h < 12 ) then
    ampm = 'AM'
  else if ( h == 12 ) then
    if ( n == 0 .and. s == 0 ) then
      ampm = 'Noon'
    else
      ampm = 'PM'
    end if
  else
    h = h - 12
    if ( h < 12 ) then
      ampm = 'PM'
    else if ( h == 12 ) then
      if ( n == 0 .and. s == 0 ) then
        ampm = 'Midnight'
      else
        ampm = 'AM'
      end if
    end if
  end if

  write ( *, '(i2,1x,a,1x,i4,2x,i2,a1,i2.2,a1,i2.2,a1,i3.3,1x,a)' ) &
    d, trim ( month(m) ), y, h, ':', n, ':', s, '.', mm, trim ( ampm )

  return
end