program main

!*****************************************************************************80
!
!! poisson_2d_exact_test() tests poisson_2d_exact().
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    05 June 2025
!
!  Author:
!
!    John Burkardt
!
  implicit none

  integer, parameter :: rk8 = kind ( 1.0D+00 )

  integer, parameter :: n = 5

  real ( kind = rk8 ) f(n)
  real ( kind = rk8 ) r(n)
  real ( kind = rk8 ) r8vec_norm_rms
  real ( kind = rk8 ) u(n)
  real ( kind = rk8 ) ux(n)
  real ( kind = rk8 ) uy(n)
  real ( kind = rk8 ) uxx(n)
  real ( kind = rk8 ) uxy(n)
  real ( kind = rk8 ) uyy(n)
  real ( kind = rk8 ) x(n)
  real ( kind = rk8 ) y(n)

  call timestamp ( )
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'poisson_2d_exact_test():'
  write ( *, '(a)' ) '  Fortran90 version'
  write ( *, '(a)' ) '  Test poisson_2d_exact().'

  call random_number ( harvest = x(1:n) )
  call random_number ( harvest = y(1:n) )

  call poisson_2d_exact ( n, x, y, u, ux, uy, uxx, uxy, uyy )
  f(1:n) = 0.0D+00
  r = uxx + uyy + f

  write ( *,'(a,g14.6)' ) '  RMS norm of residuals = ', r8vec_norm_rms ( n, r )
!
!  Terminate.
!
  write ( *, '(a)' ) ''
  write ( *, '(a)' ) 'poisson_2d_exact_test():'
  write ( *, '(a)' ) '  Normal end of execution.'
  write ( *, '(a)' ) ''
  call timestamp ( )

  return
end
function r8vec_norm_rms ( n, a )

!*****************************************************************************80
!
!! r8vec_norm_rms() returns the RMS norm of an R8VEC.
!
!  Discussion:
!
!    An R8VEC is a vector of R8's.
!
!    The vector RMS norm is defined as:
!
!      R8VEC_NORM_RMS = sqrt ( sum ( 1 <= I <= N ) A(I)^2 / N ).
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    26 October 2011
!
!  Author:
!
!    John Burkardt
!
!  Input:
!
!    integer N, the number of entries in A.
!
!    real ( kind = rk8 ) A(N), the vector.
!
!  Output:
!
!    real ( kind = rk8 ) R8VEC_NORM_RMS, the RMS norm of A.
!
  implicit none

  integer, parameter :: rk8 = kind ( 1.0D+00 )

  integer n

  real ( kind = rk8 ) a(n)
  real ( kind = rk8 ) r8vec_norm_rms

  r8vec_norm_rms = sqrt ( sum ( a(1:n) ** 2 ) / real ( n, kind = rk8 ) )

  return
end
subroutine timestamp ( )

!*****************************************************************************80
!
!! timestamp() prints the current YMDHMS date as a time stamp.
!
!  Example:
!
!    31 May 2001   9:45:54.872 AM
!
!  Licensing:
!
!    This code is distributed under the MIT license.
!
!  Modified:
!
!    15 August 2021
!
!  Author:
!
!    John Burkardt
!
  implicit none

  character ( len = 8 ) ampm
  integer d
  integer h
  integer m
  integer mm
  character ( len = 9 ), parameter, dimension(12) :: month = (/ &
    'January  ', 'February ', 'March    ', 'April    ', &
    'May      ', 'June     ', 'July     ', 'August   ', &
    'September', 'October  ', 'November ', 'December ' /)
  integer n
  integer s
  integer values(8)
  integer y

  call date_and_time ( values = values )

  y = values(1)
  m = values(2)
  d = values(3)
  h = values(5)
  n = values(6)
  s = values(7)
  mm = values(8)

  if ( h < 12 ) then
    ampm = 'AM'
  else if ( h == 12 ) then
    if ( n == 0 .and. s == 0 ) then
      ampm = 'Noon'
    else
      ampm = 'PM'
    end if
  else
    h = h - 12
    if ( h < 12 ) then
      ampm = 'PM'
    else if ( h == 12 ) then
      if ( n == 0 .and. s == 0 ) then
        ampm = 'Midnight'
      else
        ampm = 'AM'
      end if
    end if
  end if

  write ( *, '(i2.2,1x,a,1x,i4,2x,i2,a1,i2.2,a1,i2.2,a1,i3.3,1x,a)' ) &
    d, trim ( month(m) ), y, h, ':', n, ':', s, '.', mm, trim ( ampm )

  return
end