program main

!*****************************************************************************80
!
!! MAIN is the main program for QUAD_MPI.
!
!  Discussion:
!
!    Process 0 reads the name of a quadrature rule file, 
!    reads the R, W and X files, and sends a subset of the W and X data
!    to each process (including itself!).
!
!    Process I evaluates F(X) at the assigned points and returns the
!    weighted sum to Process 0.
!
!    Process 0 adds up the contributions and reports the integral estimate.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    05 May 2008
!
!  Author:
!
!    John Burkardt
!
  implicit none
!
!  For computation with a true MPI library:
!
  include 'mpif.h'
!
!  For computation with a simulated MPI library for one processor:
!
! include 'mpi_stubs_f90.h'

  integer ( kind = 4 ) arg_num
  integer ( kind = 4 ) dim
  integer ( kind = 4 ) dim_num
  integer ( kind = 4 ) dim_num2
  integer ( kind = 4 ) error_flag
  real    ( kind = 8 ), allocatable, dimension ( : ) :: f_proc
  integer ( kind = 4 ) i
  integer ( kind = 4 ) i4_div_rounded
  integer ( kind = 4 ) iarg
  integer ( kind = 4 ) iargc
  integer ( kind = 4 ) ierror
  real    ( kind = 8 ) integral
  integer ( kind = 4 ) ios
  logical more
  integer ( kind = 4 ) point_num
  integer ( kind = 4 ) point_num_proc
  integer ( kind = 4 ) point_num2
  integer ( kind = 4 ) problem
  integer ( kind = 4 ) process
  integer ( kind = 4 ) process_id
  integer ( kind = 4 ), parameter :: process_master = 0
  integer ( kind = 4 ) process_number
  integer ( kind = 4 ) process_remain
  real    ( kind = 8 ) quad
  real    ( kind = 8 ) quad_err
  character ( len = 80 ) quad_filename
  real    ( kind = 8 ) quad_proc
  character ( len = 80 ) quad_r_filename
  character ( len = 80 ) quad_w_filename
  character ( len = 80 ) quad_x_filename
  real    ( kind = 8 ), allocatable, dimension ( :, : ) :: r
  integer ( kind = 4 ) source
  integer ( kind = 4 ) status(MPI_Status_size)
  character ( len = 80 ) string
  integer ( kind = 4 ) tag
  integer ( kind = 4 ) target
  integer ( kind = 4 ) task_hi
  integer ( kind = 4 ) task_lo
  integer ( kind = 4 ) task_proc
  integer ( kind = 4 ) task_remain
  real    ( kind = 8 ) volume1
  real    ( kind = 8 ), allocatable, dimension ( : ) :: w
  real    ( kind = 8 ), allocatable, dimension ( : ) :: w_proc
  real    ( kind = 8 ) wtime_diff
  real    ( kind = 8 ) wtime_start
  real    ( kind = 8 ) wtime_stop
  real    ( kind = 8 ), allocatable, dimension ( :, : ) :: x
  real    ( kind = 8 ), allocatable, dimension ( :, : ) :: x_proc
!
!  INITIALIZE PARALLEL PROCESSING.
!
  call MPI_Init ( error_flag )

  call MPI_Comm_size ( MPI_COMM_WORLD, process_number, error_flag )

  call MPI_Comm_rank ( MPI_COMM_WORLD, process_id, error_flag )
!
!  Process 0 reads in the quadrature rule, and parcels out the
!  evaluation points among the processes.
!
  if ( process_id == process_master ) then

    wtime_start = MPI_Wtime ( )

    call timestamp ( )

    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'QUAD_MPI'
    write ( *, '(a)' ) '  FORTRAN90/MPI version'
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) '  Estimate the integral of a function F(X)'
    write ( *, '(a)' ) '  defined over a multidimensional domain'
    write ( *, '(a)' ) '  using a quadrature rule stored in 3 files.'
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) '  Use MPI to divide the computation among'
    write ( *, '(a)' ) '  multiple processes.'
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) '  The parallel processing is carried out as follows,'
    write ( *, '(a)' ) '  with process 0 playing the role of "master":'
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) '  Process 0:'
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) '  * Reads 3 files defining a quadrature rule.'
    write ( *, '(a)' ) '  * Divides the quadrature rule into PROC_NUM'
    write ( *, '(a)' ) '    portions, sending one portion to each processor'
    write ( *, '(a)' ) '    (including itself).'
    write ( *, '(a)' ) '  * Carries out its portion of the computation.'
    write ( *, '(a)' ) '  * Collects and sums the contributions from'
    write ( *, '(a)' ) '    other processes.'
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) '  Process I:'
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) '  * Receives one portion of the quadrature rule;'
    write ( *, '(a)' ) '  * Carries out its portion of the computation.'
    write ( *, '(a)' ) '  * Sends its contribution to process 0.'
!
!  Get the number of command line arguments.
!
    arg_num = iargc ( )
!
!  Get the quadrature file root name:
!
    if ( 1 <= arg_num ) then

      iarg = 1
      call getarg ( iarg, quad_filename )

    else

      write ( *, '(a)' ) ' '
      write ( *, '(a)' ) 'QUAD_MPI:'
      write ( *, '(a)' ) '  Enter the "root" name of the quadrature files.'

      read ( *, '(a)' ) quad_filename

    end if
!
!  Create the names of:
!    the quadrature X file;
!    the quadrature W file;
!    the quadrature R file.
!
    quad_x_filename = trim ( quad_filename ) // '_x.txt'
    quad_w_filename = trim ( quad_filename ) // '_w.txt'
    quad_r_filename = trim ( quad_filename ) // '_r.txt'
!
!  Summarize the input.
!
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'QUAD_MPI: User input:'
    write ( *, '(a)' ) '  Quadrature rule X file = "' &
      // trim ( quad_x_filename ) // '".'
    write ( *, '(a)' ) '  Quadrature rule W file = "' &
      // trim ( quad_w_filename ) // '".'
    write ( *, '(a)' ) '  Quadrature rule R file = "' &
      // trim ( quad_r_filename ) // '".'
!
!  Read the X file.
!
    call dtable_header_read ( quad_x_filename, dim_num, point_num )

    write ( *, '(a)' ) ' '
    write ( *, '(a,i8)' ) '  Spatial dimension = ', dim_num
    write ( *, '(a,i8)' ) '  Number of points  = ', point_num
    write ( *, '(a)' ) ' '

    allocate ( x(dim_num,point_num) )

    call dtable_data_read ( quad_x_filename, dim_num, point_num, x )
!
!  Read the W file.
!
    call dtable_header_read ( quad_w_filename, dim_num2, point_num2 )

    if ( dim_num2 /= 1 ) then
      write ( *, '(a)' ) ' '
      write ( *, '(a)' ) 'QUAD_MPI - Fatal error!'
      write ( *, '(a)' ) '  The quadrature weight file should have exactly'
      write ( *, '(a)' ) '  one value on each line.'
      stop
    end if

    if ( point_num2 /= point_num ) then
      write ( *, '(a)' ) ' '
      write ( *, '(a)' ) 'QUAD_MPI - Fatal error!'
      write ( *, '(a)' ) '  The quadrature weight file should have exactly'
      write ( *, '(a)' ) '  the same number of lines as the abscissa file.'
      stop
    end if

    allocate ( w(point_num) )

    call dtable_data_read ( quad_w_filename, 1, point_num, w )
!
!  Read the R file.
!
    call dtable_header_read ( quad_r_filename, dim_num2, point_num2 )

    if ( dim_num2 /= dim_num ) then
      write ( *, '(a)' ) ' '
      write ( *, '(a)' ) 'QUAD_MPI - Fatal error!'
      write ( *, '(a)' ) '  The quadrature region file should have the same'
      write ( *, '(a)' ) '  number of values on each line as the abscissa file'
      write ( *, '(a)' ) '  does.'
      stop
    end if

    if ( point_num2 /= 2 ) then
      write ( *, '(a)' ) ' '
      write ( *, '(a)' ) 'QUAD_MPI - Fatal error!'
      write ( *, '(a)' ) '  The quadrature region file should have two lines.'
      stop
    end if

    allocate ( r(dim_num,2) )

    call dtable_data_read ( quad_r_filename, dim_num, 2, r )
!
!  Rescale the weights, and translate the abscissas.
!
    volume1 = abs ( product ( r(1:dim_num,2) - r(1:dim_num,1) ) )

    problem = 28
!
!  Set problem data to default values.
!
    call p28_exact ( dim_num, integral )
!
!  Map the abscissas to the [0,1] hypercube.
!
    do dim = 1, dim_num
      x(dim,1:point_num) = ( x(dim,1:point_num) - r(dim,1) ) &
                         / ( r(dim,2)           - r(dim,1) )
    end do

  end if
!
!  We have POINT_NUM tasks to carry out, and PROCESS_NUMBER processors.
!
!  We assign tasks TASK_LO to TASK_HI to processor PROCESS.
!
!  The master process BROADCASTS to all processes:
!
!    DIM_NUM
!
!  The master process SENDS to PROCESS:
!
!    TASK_PROC = TASK_HI + 1 - TASK_LO;
!    W(TASK_LO:TASK_HI)
!    X(1:DIM_NUM,TASK_LO:TASK:HI)
!
!  Process PROCESS RECEIVES the data, evaluates
!
!    QUAD_PROC = sum ( TASK_LO <= TASK <= TASK_HI ) W(TASK) * F(X(:,TASK) )
!
!  and SENDS QUAD_PROC back to the master process.
!
!  While PROCESS 0 also does its share of the work, we don't allow it
!  to SEND or RECEIVE messages to itself.
!
!  PROCESS 0 sums up the values of QUAD_PROC to produce QUAD, 
!  the estimate for the integral.
!
  source = process_master
  call MPI_Bcast ( dim_num, 1, MPI_INTEGER, source, MPI_COMM_WORLD, ierror )

  if ( process_id == process_master ) then

    task_hi = 0

    task_remain = point_num
    process_remain = process_number

    do process = 0, process_number - 1

      task_proc = i4_div_rounded ( task_remain, process_remain )

      process_remain = process_remain - 1
      task_remain = task_remain - task_proc

      task_lo = task_hi + 1
      task_hi = task_hi + task_proc

      if ( process == process_master ) then

        point_num_proc = task_proc

        allocate ( w_proc(1:point_num_proc) )
        w_proc(1:point_num_proc) = w(task_lo:task_hi)

        allocate ( x_proc(1:dim_num,1:point_num_proc) )
        x_proc(1:dim_num,1:point_num_proc) = x(1:dim_num,task_lo:task_hi)

      else

        target = process
        tag = 1
        call MPI_Send ( task_proc, 1, &
          MPI_INTEGER, target, tag, MPI_COMM_WORLD, ierror )

        target = process
        tag = 2
        call MPI_Send ( w(task_lo:task_hi), task_proc, &
          MPI_DOUBLE_PRECISION, target, tag, MPI_COMM_WORLD, ierror )

        target = process
        tag = 3
        call MPI_Send ( x(1:dim_num,task_lo:task_hi), &
          dim_num * task_proc, &
          MPI_DOUBLE_PRECISION, target, tag, MPI_COMM_WORLD, ierror )

      end if

    end do

    quad = 0.0D+00

  else

    source = process_master
    tag = 1

    call MPI_Recv ( point_num_proc, 1, &
      MPI_INTEGER, source, tag, MPI_COMM_WORLD, status, ierror )

    allocate ( w_proc(1:point_num_proc) )

    source = process_master
    tag = 2

    call MPI_Recv ( w_proc, point_num_proc, &
      MPI_DOUBLE_PRECISION, source, tag, MPI_COMM_WORLD, status, ierror )

    allocate ( x_proc(1:dim_num,1:point_num_proc) )

    source = process_master
    tag = 3

    call MPI_Recv ( x_proc, dim_num * point_num_proc, &
      MPI_DOUBLE_PRECISION, source, tag, MPI_COMM_WORLD, status, ierror )

  end if
!
!  Each process evaluates the function at the abscissas.
!
  allocate ( f_proc(1:point_num_proc) )

  call p28_f ( dim_num, point_num_proc, x_proc, f_proc )
!
!  Each process weights their points.
!
  quad_proc = dot_product ( w_proc(1:point_num_proc), f_proc(1:point_num_proc) )

  write ( *, '(a,i8,a,g14.6)' ) &
    '  Process ', process_id, ' contributes QUAD_PROC = ', quad_proc
!
!  Each process sends its value of QUAD_PROC to the master process, to
!  be summed in QUAD.
!
  call MPI_Reduce ( quad_proc, quad, 1, MPI_DOUBLE_PRECISION, MPI_SUM, &
    process_master, MPI_COMM_WORLD, ierror )

  deallocate ( f_proc )
  deallocate ( w_proc )
  deallocate ( x_proc )
!
!  Compute the weighted estimate.
!
  if ( process_id == process_master ) then

    quad = quad / volume1

    quad_err = abs ( quad - integral )

    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) &
      '  Prob   Dim      Points       Approx          Exact           Error'
    write ( *, '(a)' ) ' '
    write ( *, '(2x,i4,2x,i4,2x,i10,2x,g14.6,2x,g14.6,2x,g14.6)' ) &
      problem, dim_num, point_num, quad, integral, quad_err

    deallocate ( r )
    deallocate ( w )
    deallocate ( x )

    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'QUAD_MPI:'
    write ( *, '(a)' ) '  Normal end of execution.'
    write ( *, '(a)' ) ' '
    call timestamp ( )

    wtime_stop = MPI_Wtime ( )

    wtime_diff = wtime_stop - wtime_start

    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'QUAD_MPI:'
    write ( *, '(a,g14.6)' ) '  MPI Wallclock elapsed seconds = ', wtime_diff

  end if
!
!  TERMINATE PARALLEL PROCESSING.
!
  call MPI_Finalize ( error_flag )

  stop
end
subroutine ch_cap ( c )

!*****************************************************************************80
!
!! CH_CAP capitalizes a single character.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    19 July 1998
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input/output, character C, the character to capitalize.
!
  implicit none

  character c
  integer ( kind = 4 ) itemp

  itemp = ichar ( c )

  if ( 97 <= itemp .and. itemp <= 122 ) then
    c = char ( itemp - 32 )
  end if

  return
end
function ch_eqi ( c1, c2 )

!*****************************************************************************80
!
!! CH_EQI is a case insensitive comparison of two characters for equality.
!
!  Example:
!
!    CH_EQI ( 'A', 'a' ) is .TRUE.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    28 July 2000
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, character C1, C2, the characters to compare.
!
!    Output, logical CH_EQI, the result of the comparison.
!
  implicit none

  logical ch_eqi
  character c1
  character c1_cap
  character c2
  character c2_cap

  c1_cap = c1
  c2_cap = c2

  call ch_cap ( c1_cap )
  call ch_cap ( c2_cap )

  if ( c1_cap == c2_cap ) then
    ch_eqi = .true.
  else
    ch_eqi = .false.
  end if

  return
end
subroutine ch_to_digit ( c, digit )

!*****************************************************************************80
!
!! CH_TO_DIGIT returns the integer value of a base 10 digit.
!
!  Example:
!
!     C   DIGIT
!    ---  -----
!    '0'    0
!    '1'    1
!    ...  ...
!    '9'    9
!    ' '    0
!    'X'   -1
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    04 August 1999
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, character C, the decimal digit, '0' through '9' or blank
!    are legal.
!
!    Output, integer ( kind = 4 ) DIGIT, the corresponding integer value.  
!    If C was 'illegal', then DIGIT is -1.
!
  implicit none

  character c
  integer ( kind = 4 ) digit

  if ( lge ( c, '0' ) .and. lle ( c, '9' ) ) then

    digit = ichar ( c ) - 48

  else if ( c == ' ' ) then

    digit = 0

  else

    digit = -1

  end if

  return
end
subroutine dtable_data_read ( input_file_name, m, n, table )

!*****************************************************************************80
!
!! DTABLE_DATA_READ reads data from a DTABLE file.
!
!  Discussion:
!
!    The file may contain more than N points, but this routine will
!    return after reading N of them.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    26 January 2005
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, character ( len = * ) INPUT_FILE_NAME, the name of the input file.
!
!    Input, integer ( kind = 4 ) M, the spatial dimension.
!
!    Input, integer ( kind = 4 ) N, the number of points.
!
!    Output, real ( kind = 8 ) TABLE(M,N), the table data.
!
  implicit none

  integer ( kind = 4 ) m
  integer ( kind = 4 ) n

  integer ( kind = 4 ) ierror
  character ( len = * ) input_file_name
  integer ( kind = 4 ) input_status
  integer ( kind = 4 ) input_unit
  integer ( kind = 4 ) j
  character ( len = 255 ) line
  real ( kind = 8 ) table(m,n)
  real ( kind = 8 ) x(m)

  ierror = 0

  call get_unit ( input_unit )

  open ( unit = input_unit, file = input_file_name, status = 'old', &
    iostat = input_status )

  if ( input_status /= 0 ) then
    ierror = 1
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'DTABLE_DATA_READ - Fatal error!'
    write ( *, '(a,i8)' ) '  Could not open the input file "' // &
      trim ( input_file_name ) // '" on unit ', input_unit
    stop
  end if

  j = 0

  do while ( j < n )

    read ( input_unit, '(a)', iostat = input_status ) line

    if ( input_status /= 0 ) then
      write ( *, '(a)' ) ' '
      write ( *, '(a)' ) 'DTABLE_DATA_READ - Fatal error!'
      write ( *, '(a)' ) '  Error while reading lines of data.'
      write ( *, '(a,i8)' ) '  Number of values expected per line M = ', m
      write ( *, '(a,i8)' ) '  Number of data lines read, J =         ', j
      write ( *, '(a,i8)' ) '  Number of data lines needed, N =       ', n
      stop
    end if

    if ( line(1:1) == '#' .or. len_trim ( line ) == 0 ) then
      cycle
    end if

    call s_to_r8vec ( line, m, x, ierror )

    if ( ierror /= 0 ) then
      cycle
    end if

    j = j + 1

    table(1:m,j) = x(1:m)

  end do

  close ( unit = input_unit )

  return
end
subroutine dtable_header_read ( input_file_name, m, n )

!*****************************************************************************80
!
!! DTABLE_HEADER_READ reads the header from a DTABLE file.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    07 September 2004
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, character ( len = * ) INPUT_FILE_NAME, the name of the input file.
!
!    Output, integer ( kind = 4 ) M, spatial dimension.
!
!    Output, integer ( kind = 4 ) N, the number of points. 
!
  implicit none

  character ( len = * ) input_file_name
  integer ( kind = 4 ) m
  integer ( kind = 4 ) n

  call file_column_count ( input_file_name, m )

  if ( m <= 0 ) then
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'DTABLE_HEADER_READ - Fatal error!'
    write ( *, '(a)' ) '  There was some kind of I/O problem while trying'
    write ( *, '(a)' ) '  to count the number of data columns in'
    write ( *, '(a)' ) '  the file "' // trim ( input_file_name ) // '".'
    stop
  end if

  call file_row_count ( input_file_name, n )

  if ( n <= 0 ) then
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'DTABLE_HEADER_READ - Fatal error!'
    write ( *, '(a)' ) '  There was some kind of I/O problem while trying'
    write ( *, '(a)' ) '  to count the number of data rows in'
    write ( *, '(a)' ) '  the file "' // trim ( input_file_name ) // '".'
    stop
  end if

  return
end
subroutine file_column_count ( input_file_name, column_num )

!*****************************************************************************80
!
!! FILE_COLUMN_COUNT counts the number of columns in the first line of a file.
!
!  Discussion:
!
!    The file is assumed to be a simple text file.
!
!    Most lines of the file is presumed to consist of COLUMN_NUM words,
!    separated by spaces.  There may also be some blank lines, and some 
!    comment lines,
!    which have a "#" in column 1.
!
!    The routine tries to find the first non-comment non-blank line and
!    counts the number of words in that line.
!
!    If all lines are blanks or comments, it goes back and tries to analyze
!    a comment line.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    21 June 2001
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, character ( len = * ) INPUT_FILE_NAME, the name of the file.
!
!    Output, integer ( kind = 4 ) COLUMN_NUM, the number of columns in the file.
!
  implicit none

  integer ( kind = 4 ) column_num
  logical got_one
  character ( len = * ) input_file_name
  integer ( kind = 4 ) input_status
  integer ( kind = 4 ) input_unit
  character ( len = 256 ) line
!
!  Open the file.
!
  call get_unit ( input_unit )

  open ( unit = input_unit, file = input_file_name, status = 'old', &
    form = 'formatted', access = 'sequential', iostat = input_status )

  if ( input_status /= 0 ) then
    column_num = -1
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'FILE_COLUMN_COUNT - Fatal error!'
    write ( *, '(a,i8)' ) '  Could not open the input file "' &
      // trim ( input_file_name ) // '" on unit ', input_unit
    return
  end if
!
!  Read one line, but skip blank lines and comment lines.
!
  got_one = .false.

  do

    read ( input_unit, '(a)', iostat = input_status ) line

    if ( input_status /= 0 ) then
      exit
    end if

    if ( len_trim ( line ) == 0 ) then
      cycle
    end if

    if ( line(1:1) == '#' ) then
      cycle
    end if

    got_one = .true.
    exit

  end do

  if ( .not. got_one ) then

    rewind ( input_unit )

    do

      read ( input_unit, '(a)', iostat = input_status ) line

      if ( input_status /= 0 ) then
        exit
      end if

      if ( len_trim ( line ) == 0 ) then
        cycle
      end if

      got_one = .true.
      exit

    end do

  end if

  close ( unit = input_unit )

  if ( .not. got_one ) then
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'FILE_COLUMN_COUNT - Warning!'
    write ( *, '(a)' ) '  The file does not seem to contain any data.'
    column_num = -1
    return
  end if

  call s_word_count ( line, column_num )

  return
end
subroutine file_row_count ( input_file_name, row_num )

!*****************************************************************************80
!
!! FILE_ROW_COUNT counts the number of row records in a file.
!
!  Discussion:
!
!    It does not count lines that are blank, or that begin with a
!    comment symbol '#'.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    06 March 2003
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, character ( len = * ) INPUT_FILE_NAME, the name of the input file.
!
!    Output, integer ( kind = 4 ) ROW_NUM, the number of rows found.
!
  implicit none

  integer ( kind = 4 ) bad_num
  integer ( kind = 4 ) comment_num
  integer ( kind = 4 ) ierror
  character ( len = * ) input_file_name
  integer ( kind = 4 ) input_status
  integer ( kind = 4 ) input_unit
  character ( len = 100 ) line
  integer ( kind = 4 ) record_num
  integer ( kind = 4 ) row_num

  call get_unit ( input_unit )

  open ( unit = input_unit, file = input_file_name, status = 'old', &
    iostat = input_status )

  if ( input_status /= 0 ) then
    row_num = -1;
    ierror = 1
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'FILE_ROW_COUNT - Fatal error!'
    write ( *, '(a,i8)' ) '  Could not open the input file "' // &
      trim ( input_file_name ) // '" on unit ', input_unit
    stop
  end if

  comment_num = 0
  row_num = 0
  record_num = 0
  bad_num = 0

  do

    read ( input_unit, '(a)', iostat = input_status ) line

    if ( input_status /= 0 ) then
      ierror = record_num
      exit
    end if

    record_num = record_num + 1

    if ( line(1:1) == '#' ) then
      comment_num = comment_num + 1
      cycle
    end if

    if ( len_trim ( line ) == 0 ) then
      comment_num = comment_num + 1
      cycle
    end if

    row_num = row_num + 1

  end do

  close ( unit = input_unit )

  return
end
subroutine get_unit ( iunit )

!*****************************************************************************80
!
!! GET_UNIT returns a free FORTRAN unit number.
!
!  Discussion:
!
!    A "free" FORTRAN unit number is an integer between 1 and 99 which
!    is not currently associated with an I/O device.  A free FORTRAN unit
!    number is needed in order to open a file with the OPEN command.
!
!    If IUNIT = 0, then no free FORTRAN unit could be found, although
!    all 99 units were checked (except for units 5, 6 and 9, which
!    are commonly reserved for console I/O).
!
!    Otherwise, IUNIT is an integer between 1 and 99, representing a
!    free FORTRAN unit.  Note that GET_UNIT assumes that units 5 and 6
!    are special, and will never return those values.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    18 September 2005
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Output, integer ( kind = 4 ) IUNIT, the free unit number.
!
  implicit none

  integer ( kind = 4 ) i
  integer ( kind = 4 ) ios
  integer ( kind = 4 ) iunit
  logical lopen

  iunit = 0

  do i = 1, 99

    if ( i /= 5 .and. i /= 6 .and. i /= 9 ) then

      inquire ( unit = i, opened = lopen, iostat = ios )

      if ( ios == 0 ) then
        if ( .not. lopen ) then
          iunit = i
          return
        end if
      end if

    end if

  end do

  return
end
function i4_div_rounded ( a, b )

!*****************************************************************************80
!
!! I4_DIV_ROUNDED computes the rounded result of I4 division.
!
!  Discussion:
!
!    This routine computes C = A / B, where A, B and C are integers
!    and C is the closest integer value to the exact real result.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    20 October 2007
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, integer ( kind = 4 ) A, B, the number to be divided,
!    and the divisor.
!
!    Output, integer ( kind = 4 ) I4_DIV_ROUNDED, the rounded result
!    of the division.
!
  implicit none

  integer ( kind = 4 ) a
  integer ( kind = 4 ) a_abs
  integer ( kind = 4 ) b
  integer ( kind = 4 ) b_abs
  integer ( kind = 4 ) c
  integer ( kind = 4 ) c_abs
  integer ( kind = 4 ) c_s
  integer ( kind = 4 ) i4_div_rounded
  integer ( kind = 4 ) i4_huge
  integer ( kind = 4 ) i4_sign

  if ( a == 0 ) then

    c_abs = i4_huge ( )
    c_s = i4_sign ( b )

  else

    a_abs = abs ( a )
    b_abs = abs ( b )
    c_s = i4_sign ( a ) * i4_sign ( b )

    c_abs = a_abs / b_abs

    if ( ( 2 * c_abs + 1 ) * b_abs < 2 * a_abs ) then
      c_abs = c_abs + 1
    end if

  end if

  c = c_s * c_abs

  i4_div_rounded = c

  return
end
function i4_huge ( )

!*****************************************************************************80
!
!! I4_HUGE returns a "huge" I4.
!
!  Discussion:
!
!    On an IEEE 32 bit machine, I4_HUGE should be 2**31 - 1, and its
!    bit pattern should be
!
!     01111111111111111111111111111111
!
!    In this case, its numerical value is 2147483647.
!
!    Using the Dec/Compaq/HP Alpha FORTRAN compiler FORT, I could
!    use I4_HUGE() and HUGE interchangeably.
!
!    However, when using the G95, the values returned by HUGE were
!    not equal to 2147483647, apparently, and were causing severe
!    and obscure errors in my random number generator, which needs to
!    add I4_HUGE to the seed whenever the seed is negative.  So I
!    am backing away from invoking HUGE, whereas I4_HUGE is under
!    my control.
!
!    Explanation: because under G95 the default integer type is 64 bits!
!    So HUGE ( 1 ) = a very very huge integer indeed, whereas
!    I4_HUGE ( ) = the same old 32 bit big value.
!
!    An I4 is an integer ( kind = 4 ) value.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    26 January 2007
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Output, integer ( kind = 4 ) I4_HUGE, a "huge" I4.
!
  implicit none

  integer ( kind = 4 ) i4
  integer ( kind = 4 ) i4_huge

  i4_huge = 2147483647

  return
end
function i4_sign ( x )

!*****************************************************************************80
!
!! I4_SIGN evaluates the sign of an I4.
!
!  Discussion:
!
!    An I4 is an integer ( kind = 4 ) value.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    27 March 2004
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, integer ( kind = 4 ) X, the number whose sign is desired.
!
!    Output, integer ( kind = 4 ) I4_SIGN, the sign of X:
!
  implicit none

  integer ( kind = 4 ) i4_sign
  integer ( kind = 4 ) x

  if ( x < 0 ) then
    i4_sign = -1
  else
    i4_sign = +1
  end if

  return
end
subroutine s_to_i4 ( s, ival, ierror, length )

!*****************************************************************************80
!
!! S_TO_I4 reads an I4 from a string.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    28 June 2000
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, character ( len = * ) S, a string to be examined.
!
!    Output, integer ( kind = 4 ) IVAL, the integer value read from the string.
!    If the string is blank, then IVAL will be returned 0.
!
!    Output, integer ( kind = 4 ) IERROR, an error flag.
!    0, no error.
!    1, an error occurred.
!
!    Output, integer ( kind = 4 ) LENGTH, the number of characters of S 
!    used to make IVAL.
!
  implicit none

  character c
  integer ( kind = 4 ) i
  integer ( kind = 4 ) ierror
  integer ( kind = 4 ) isgn
  integer ( kind = 4 ) istate
  integer ( kind = 4 ) ival
  integer ( kind = 4 ) length
  character ( len = * ) s

  ierror = 0
  istate = 0
  isgn = 1
  ival = 0

  do i = 1, len_trim ( s )

    c = s(i:i)
!
!  Haven't read anything.
!
    if ( istate == 0 ) then

      if ( c == ' ' ) then

      else if ( c == '-' ) then
        istate = 1
        isgn = -1
      else if ( c == '+' ) then
        istate = 1
        isgn = + 1
      else if ( lle ( '0', c ) .and. lle ( c, '9' ) ) then
        istate = 2
        ival = ichar ( c ) - ichar ( '0' )
      else
        ierror = 1
        return
      end if
!
!  Have read the sign, expecting digits.
!
    else if ( istate == 1 ) then

      if ( c == ' ' ) then

      else if ( lle ( '0', c ) .and. lle ( c, '9' ) ) then
        istate = 2
        ival = ichar ( c ) - ichar ( '0' )
      else
        ierror = 1
        return
      end if
!
!  Have read at least one digit, expecting more.
!
    else if ( istate == 2 ) then

      if ( lle ( '0', c ) .and. lle ( c, '9' ) ) then
        ival = 10 * ival + ichar ( c ) - ichar ( '0' )
      else
        ival = isgn * ival
        length = i - 1
        return
      end if

    end if

  end do
!
!  If we read all the characters in the string, see if we're OK.
!
  if ( istate == 2 ) then
    ival = isgn * ival
    length = len_trim ( s )
  else
    ierror = 1
    length = 0
  end if

  return
end
subroutine s_to_r8 ( s, dval, ierror, length )

!*****************************************************************************80
!
!! S_TO_R8 reads an R8 from a string.
!
!  Discussion:
!
!    The routine will read as many characters as possible until it reaches
!    the end of the string, or encounters a character which cannot be
!    part of the number.
!
!    Legal input is:
!
!       1 blanks,
!       2 '+' or '-' sign,
!       2.5 blanks
!       3 integer part,
!       4 decimal point,
!       5 fraction part,
!       6 'E' or 'e' or 'D' or 'd', exponent marker,
!       7 exponent sign,
!       8 exponent integer part,
!       9 exponent decimal point,
!      10 exponent fraction part,
!      11 blanks,
!      12 final comma or semicolon,
!
!    with most quantities optional.
!
!  Example:
!
!    S                 DVAL
!
!    '1'               1.0
!    '     1   '       1.0
!    '1A'              1.0
!    '12,34,56'        12.0
!    '  34 7'          34.0
!    '-1E2ABCD'        -100.0
!    '-1X2ABCD'        -1.0
!    ' 2E-1'           0.2
!    '23.45'           23.45
!    '-4.2E+2'         -420.0
!    '17d2'            1700.0
!    '-14e-2'         -0.14
!    'e2'              100.0
!    '-12.73e-9.23'   -12.73 * 10.0**(-9.23)
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    07 September 2004
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, character ( len = * ) S, the string containing the
!    data to be read.  Reading will begin at position 1 and
!    terminate at the end of the string, or when no more
!    characters can be read to form a legal real.  Blanks,
!    commas, or other nonnumeric data will, in particular,
!    cause the conversion to halt.
!
!    Output, real ( kind = 8 ) DVAL, the value read from the string.
!
!    Output, integer ( kind = 4 ) IERROR, error flag.
!    0, no errors occurred.
!    1, 2, 6 or 7, the input number was garbled.  The
!    value of IERROR is the last type of input successfully
!    read.  For instance, 1 means initial blanks, 2 means
!    a plus or minus sign, and so on.
!
!    Output, integer ( kind = 4 ) LENGTH, the number of characters read
!    to form the number, including any terminating
!    characters such as a trailing comma or blanks.
!
  implicit none

  logical ch_eqi
  character c
  real ( kind = 8 ) dval
  integer ( kind = 4 ) ierror
  integer ( kind = 4 ) ihave
  integer ( kind = 4 ) isgn
  integer ( kind = 4 ) iterm
  integer ( kind = 4 ) jbot
  integer ( kind = 4 ) jsgn
  integer ( kind = 4 ) jtop
  integer ( kind = 4 ) length
  integer ( kind = 4 ) nchar
  integer ( kind = 4 ) ndig
  real ( kind = 8 ) rbot
  real ( kind = 8 ) rexp
  real ( kind = 8 ) rtop
  character ( len = * ) s

  nchar = len_trim ( s )

  ierror = 0
  dval = 0.0D+00
  length = -1
  isgn = 1
  rtop = 0
  rbot = 1
  jsgn = 1
  jtop = 0
  jbot = 1
  ihave = 1
  iterm = 0

  do

    length = length + 1

    if ( nchar < length+1 ) then
      exit
    end if

    c = s(length+1:length+1)
!
!  Blank character.
!
    if ( c == ' ' ) then

      if ( ihave == 2 ) then

      else if ( ihave == 6 .or. ihave == 7 ) then
        iterm = 1
      else if ( 1 < ihave ) then
        ihave = 11
      end if
!
!  Comma.
!
    else if ( c == ',' .or. c == ';' ) then

      if ( ihave /= 1 ) then
        iterm = 1
        ihave = 12
        length = length + 1
      end if
!
!  Minus sign.
!
    else if ( c == '-' ) then

      if ( ihave == 1 ) then
        ihave = 2
        isgn = -1
      else if ( ihave == 6 ) then
        ihave = 7
        jsgn = -1
      else
        iterm = 1
      end if
!
!  Plus sign.
!
    else if ( c == '+' ) then

      if ( ihave == 1 ) then
        ihave = 2
      else if ( ihave == 6 ) then
        ihave = 7
      else
        iterm = 1
      end if
!
!  Decimal point.
!
    else if ( c == '.' ) then

      if ( ihave < 4 ) then
        ihave = 4
      else if ( 6 <= ihave .and. ihave <= 8 ) then
        ihave = 9
      else
        iterm = 1
      end if
!
!  Scientific notation exponent marker.
!
    else if ( ch_eqi ( c, 'E' ) .or. ch_eqi ( c, 'D' ) ) then

      if ( ihave < 6 ) then
        ihave = 6
      else
        iterm = 1
      end if
!
!  Digit.
!
    else if (  ihave < 11 .and. lle ( '0', c ) .and. lle ( c, '9' ) ) then

      if ( ihave <= 2 ) then
        ihave = 3
      else if ( ihave == 4 ) then
        ihave = 5
      else if ( ihave == 6 .or. ihave == 7 ) then
        ihave = 8
      else if ( ihave == 9 ) then
        ihave = 10
      end if

      call ch_to_digit ( c, ndig )

      if ( ihave == 3 ) then
        rtop = 10.0D+00 * rtop + real ( ndig, kind = 8 )
      else if ( ihave == 5 ) then
        rtop = 10.0D+00 * rtop + real ( ndig, kind = 8 )
        rbot = 10.0D+00 * rbot
      else if ( ihave == 8 ) then
        jtop = 10 * jtop + ndig
      else if ( ihave == 10 ) then
        jtop = 10 * jtop + ndig
        jbot = 10 * jbot
      end if
!
!  Anything else is regarded as a terminator.
!
    else
      iterm = 1
    end if
!
!  If we haven't seen a terminator, and we haven't examined the
!  entire string, go get the next character.
!
    if ( iterm == 1 ) then
      exit
    end if

  end do
!
!  If we haven't seen a terminator, and we have examined the
!  entire string, then we're done, and LENGTH is equal to NCHAR.
!
  if ( iterm /= 1 .and. length+1 == nchar ) then
    length = nchar
  end if
!
!  Number seems to have terminated.  Have we got a legal number?
!  Not if we terminated in states 1, 2, 6 or 7!
!
  if ( ihave == 1 .or. ihave == 2 .or. ihave == 6 .or. ihave == 7 ) then
    ierror = ihave
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) 'S_TO_R8 - Serious error!'
    write ( *, '(a)' ) '  Illegal or nonnumeric input:'
    write ( *, '(a)' ) '    ' // trim ( s )
    return
  end if
!
!  Number seems OK.  Form it.
!
  if ( jtop == 0 ) then
    rexp = 1.0D+00
  else
    if ( jbot == 1 ) then
      rexp = 10.0D+00 ** ( jsgn * jtop )
    else
      rexp = 10.0D+00 ** ( real ( jsgn * jtop, kind = 8 ) &
        / real ( jbot, kind = 8 ) )
    end if
  end if

  dval = real ( isgn, kind = 8 ) * rexp * rtop / rbot

  return
end
subroutine s_to_r8vec ( s, n, rvec, ierror )

!*****************************************************************************80
!
!! S_TO_R8VEC reads an R8VEC from a string.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    07 September 2004
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, character ( len = * ) S, the string to be read.
!
!    Input, integer ( kind = 4 ) N, the number of values expected.
!
!    Output, real ( kind = 8 ) RVEC(N), the values read from the string.
!
!    Output, integer ( kind = 4 ) IERROR, error flag.
!    0, no errors occurred.
!    -K, could not read data for entries -K through N.
!
  implicit none

  integer ( kind = 4 ) n

  integer ( kind = 4 ) i
  integer ( kind = 4 ) ierror
  integer ( kind = 4 ) ilo
  integer ( kind = 4 ) lchar
  real ( kind = 8 ) rvec(n)
  character ( len = * ) s

  i = 0
  ierror = 0
  ilo = 1

  do while ( i < n )

    i = i + 1

    call s_to_r8 ( s(ilo:), rvec(i), ierror, lchar )

    if ( ierror /= 0 ) then
      ierror = -i
      exit
    end if

    ilo = ilo + lchar

  end do

  return
end
subroutine s_word_count ( s, nword )

!*****************************************************************************80
!
!! S_WORD_COUNT counts the number of "words" in a string.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    14 April 1999
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, character ( len = * ) S, the string to be examined.
!
!    Output, integer ( kind = 4 ) NWORD, the number of "words" in the string.
!    Words are presumed to be separated by one or more blanks.
!
  implicit none

  logical blank
  integer ( kind = 4 ) i
  integer ( kind = 4 ) lens
  integer ( kind = 4 ) nword
  character ( len = * ) s

  nword = 0
  lens = len ( s )

  if ( lens <= 0 ) then
    return
  end if

  blank = .true.

  do i = 1, lens

    if ( s(i:i) == ' ' ) then
      blank = .true.
    else if ( blank ) then
      nword = nword + 1
      blank = .false.
    end if

  end do

  return
end
subroutine timestamp ( )

!*****************************************************************************80
!
!! TIMESTAMP prints the current YMDHMS date as a time stamp.
!
!  Example:
!
!    31 May 2001   9:45:54.872 AM
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    06 August 2005
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    None
!
  implicit none

  character ( len = 8 ) ampm
  integer ( kind = 4 ) d
  integer ( kind = 4 ) h
  integer ( kind = 4 ) m
  integer ( kind = 4 ) mm
  character ( len = 9 ), parameter, dimension(12) :: month = (/ &
    'January  ', 'February ', 'March    ', 'April    ', &
    'May      ', 'June     ', 'July     ', 'August   ', &
    'September', 'October  ', 'November ', 'December ' /)
  integer ( kind = 4 ) n
  integer ( kind = 4 ) s
  integer ( kind = 4 ) values(8)
  integer ( kind = 4 ) y

  call date_and_time ( values = values )

  y = values(1)
  m = values(2)
  d = values(3)
  h = values(5)
  n = values(6)
  s = values(7)
  mm = values(8)

  if ( h < 12 ) then
    ampm = 'AM'
  else if ( h == 12 ) then
    if ( n == 0 .and. s == 0 ) then
      ampm = 'Noon'
    else
      ampm = 'PM'
    end if
  else
    h = h - 12
    if ( h < 12 ) then
      ampm = 'PM'
    else if ( h == 12 ) then
      if ( n == 0 .and. s == 0 ) then
        ampm = 'Midnight'
      else
        ampm = 'AM'
      end if
    end if
  end if

  write ( *, '(i2,1x,a,1x,i4,2x,i2,a1,i2.2,a1,i2.2,a1,i3.3,1x,a)' ) &
    d, trim ( month(m) ), y, h, ':', n, ':', s, '.', mm, trim ( ampm )

  return
end
subroutine p28_exact ( dim_num, exact )

!*****************************************************************************80
!
!! P28_EXACT returns the exact integral for problem 28.
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    17 April 2003
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, integer ( kind = 4 ) DIM_NUM, the spatial dimension.
!
!    Output, real ( kind = 8 ) EXACT, the exact value of the integral.
!
  implicit none

  integer ( kind = 4 ) dim_num

  real ( kind = 8 ) exact

  exact = ( 2.0D+00 * atan ( 0.5D+00 ) )**dim_num

  return
end
subroutine p28_f ( dim_num, point_num, x, value )

!*****************************************************************************80
!
!! P28_F evaluates the integrand for problem 28.
!
!  Dimension:
!
!    N arbitrary.
!
!  Region:
!
!    0 <= X(1:DIM_NUM) <= 1
!
!  Integrand:
!
!    1 / product ( C(1:DIM_NUM)**2 + ( X(1:DIM_NUM) - Z(1:DIM_NUM) )**2 )
!
!  Exact Integral:
!
!    product ( (   arctan ( ( 1 - Z(1:DIM_NUM) ) / C(1:DIM_NUM) )
!                + arctan (       Z(1:DIM_NUM)   / C(1:DIM_NUM) ) 
!              ) / C(1:DIM_NUM)
!            )
!
!  Licensing:
!
!    This code is distributed under the GNU LGPL license. 
!
!  Modified:
!
!    03 June 2007
!
!  Author:
!
!    John Burkardt
!
!  Reference:
!
!    Alan Genz,
!    [Integral #2]
!    A Package for Testing Multiple Integration Subroutines,
!    in Numerical Integration: Recent Developments, Software
!    and Applications,
!    edited by Patrick Keast and Graeme Fairweather,
!    D Reidel, 1987, pages 337-340,
!    LC: QA299.3.N38.
!
!    Thomas Patterson,
!    [Integral #6],
!    On the Construction of a Practical Ermakov-Zolotukhin 
!    Multiple Integrator,
!    in Numerical Integration: Recent Developments, Software
!    and Applications,
!    edited by Patrick Keast and Graeme Fairweather,
!    D. Reidel, 1987, pages 269-290,
!    LC: QA299.3.N38.
!
!  Parameters:
!
!    Input, integer ( kind = 4 ) DIM_NUM, the dimension of the argument.
!
!    Input, integer ( kind = 4 ) POINT_NUM, the number of points.
!
!    Input, real ( kind = 8 ) X(DIM_NUM,POINT_NUM), the evaluation points.
!
!    Output, real ( kind = 8 ) VALUE(POINT_NUM), the function values.
!
  implicit none

  integer ( kind = 4 ) dim_num
  integer ( kind = 4 ) point_num

  integer ( kind = 4 ) point
  real ( kind = 8 ) value(point_num)
  real ( kind = 8 ) x(dim_num,point_num)

  do point = 1, point_num
    value(point) = 1.0D+00 &
      / product ( 1.0 + ( x(1:dim_num,point) - 0.5D+00 )**2 )
  end do

  return
end